sys.sql_dependencias_de_expresiones (Transact-SQL)

Se aplica a:punto de conexión de SQL Server Azure SQL Instancia administrada el punto de conexión de SQL Analytics Analytics Platform System (PDW) de SQL Analytics system (PDW) de SQL Server en Microsoft FabricWarehouse en Microsoft Fabric

Contiene una fila para cada dependencia por nombre en una entidad definida por el usuario en la base de datos actual. Esto incluye dependencias entre funciones escalares definidas por el usuario y otras funciones escalares compiladas de forma nativa y otros módulos de SQL Server. Se crea una dependencia entre dos entidades cuando una entidad, llamada entidad a la que se hace referencia, aparece por nombre en una expresión de SQL persistente de otra entidad, llamada entidad que hace la referencia. Por ejemplo, si en la definición de una vista se hace referencia a una tabla, la vista, como entidad que hace la referencia, depende de la tabla, la entidad a la que se hace referencia. Si desapareciera la tabla, la vista sería inservible.

Para obtener más información, vea Funciones escalares definidas por el usuario para OLTP en memoria.

Puede utilizar esta vista de catálogo para notificar información de dependencia de las entidades siguientes:

• Entidades enlazadas a un esquema.

• Entidades no enlazadas a un esquema.

• Entidades entre servidores y entre bases de datos. Se reportan los nombres de las entidades; sin embargo, los IDs de las entidades no se resuelven.

• Dependencias de nivel de columna en entidades enlazadas a un esquema. Se pueden devolver las dependencias de nivel de columna de los objetos no enlazados a un esquema mediante sys.dm_sql_referenced_entities.

• El DDL a nivel de servidor se activa cuando está en el contexto de la master base de datos.

Observaciones

La tabla siguiente enumera los tipos de entidades para las que se crea y mantiene la información de dependencia. La información de dependencias no se crea ni mantiene para reglas, valores predeterminados, tablas temporales, procedimientos almacenados temporales u objetos del sistema.

¹ Una tabla se rastrea como entidad de referencia solo cuando hace referencia a un módulo Transact-SQL, un tipo definido por el usuario o una colección de esquema XML en la definición de una columna computada, restricción CHECK o DEFAULT restricción.

² Cada columna utilizada en el predicado del filtro se rastrea como una entidad de referencia.

³ Los procedimientos almacenados numerados con un valor entero mayor que 1 no se rastrean ni como entidad referenciada ni como entidad referenciada.

Permisos

Requiere VIEW permiso DEFINITION en la base de datos y permiso SELECT activado sys.sql_expression_dependencies para la base de datos. De forma predeterminada, solo se concede el permiso SELECT a los miembros del rol fijo de base de datos db_owner . Cuando se conceden permisos SELECT y VIEW DEFINITION a otro usuario, el receptor puede ver todas las dependencias de la base de datos.

Ejemplos

A. Devuelve entidades que son referenciadas por otra entidad

El ejemplo siguiente devuelve las tablas y columnas a las que se hace referencia en la vista Production.vProductAndDescription. La vista depende de las entidades (tablas y columnas) devueltas en referenced_entity_name y las columnas referenced_column_name.

USE AdventureWorks2022;
GO

SELECT
    OBJECT_NAME(referencing_id) AS referencing_entity_name,
    o.type_desc AS referencing_description,
    COALESCE (COL_NAME(referencing_id, referencing_minor_id), '(n/a)') AS referencing_minor_id,
    referencing_class_desc,
    referenced_server_name,
    referenced_database_name,
    referenced_schema_name,
    referenced_entity_name,
    COALESCE (COL_NAME(referenced_id, referenced_minor_id), '(n/a)') AS referenced_column_name,
    is_caller_dependent,
    is_ambiguous
FROM sys.sql_expression_dependencies AS sed
    INNER JOIN sys.objects AS o
        ON sed.referencing_id = o.object_id
WHERE referencing_id = OBJECT_ID(N'Production.vProductAndDescription');

B. Devuelven entidades que hacen referencia a otra entidad

El ejemplo siguiente devuelve las entidades que hacen referencia a la tabla Production.Product. Las entidades devueltas en la columna referencing_entity_name dependen de la tabla Product.

USE AdventureWorks2022;
GO

SELECT
    OBJECT_SCHEMA_NAME(referencing_id) AS referencing_schema_name,
    OBJECT_NAME(referencing_id) AS referencing_entity_name,
    o.type_desc AS referencing_description,
    COALESCE (COL_NAME(referencing_id, referencing_minor_id), '(n/a)') AS referencing_minor_id,
    referencing_class_desc,
    referenced_class_desc,
    referenced_server_name,
    referenced_database_name,
    referenced_schema_name,
    referenced_entity_name,
    COALESCE (COL_NAME(referenced_id, referenced_minor_id), '(n/a)') AS referenced_column_name,
    is_caller_dependent,
    is_ambiguous
FROM sys.sql_expression_dependencies AS sed
    INNER JOIN sys.objects AS o
        ON sed.referencing_id = o.object_id
WHERE referenced_id = OBJECT_ID(N'Production.Product');

C. Devolver dependencias entre bases de datos

El siguiente ejemplo devuelve todas las dependencias entre bases de datos. El ejemplo crea primero la base de datos db1 y dos procedimientos almacenados que hacen referencia a tablas en las bases de datos db2 y db3. A continuación, se consulta la tabla sys.sql_expression_dependencies para crear informes de las dependencias entre bases de datos entre los procedimientos y las tablas. NULL se devuelve en la referenced_schema_name columna de la entidad t3 referenciada porque no se especifica un nombre de esquema para esa entidad en la definición del procedimiento.

CREATE DATABASE db1;
GO

USE db1;
GO

CREATE PROCEDURE p1 AS
SELECT * FROM db2.s1.t1;
GO

CREATE PROCEDURE p2 AS
UPDATE db3..t3
SET c1 = c1 + 1;
GO

SELECT
    OBJECT_NAME(referencing_id),
    referenced_database_name,
    referenced_schema_name,
    referenced_entity_name
FROM sys.sql_expression_dependencies
WHERE referenced_database_name IS NOT NULL;
GO

USE master;
GO

DROP DATABASE db1;

Contenido relacionado

• sys.dm_sql_referenced_entities (Transact-SQL)
• sys.dm_sql_referencing_entities (Transact-SQL)